Chapitre 3

Chapitre 3 : Langage Visual Basic



Feuilles de module

Les feuilles de module contiennent uniquement du code. Elles servent a ecrire des programmes reutilisables dans plusieurs classeurs. En exportant ces programmes, vous pourrez aussi les utiliser dans les applications qui exploitent le langage VB (Visual Basic, Access, Word, etc.).
-Au besoin, ouvrez le classeur Macro2.xls
Affichons la barre d'outils Visual Basic.
-Cliquez avec le bouton droit sur n'importe quelle barre d'outils
-Cliquez Visual Basic dans le menu contextuel
Passons a Visual Basic.
-Cliquez Visual Basic Editor dans la barre d'outils Visual Basic
Ajoutons une nouvelle feuille de module.
-Cliquez la fleche de Ajouter une feuille utilisateur puis cliquez Module dans la liste.
Une nouvelle feuille de module Module2 apparait.


Procedures

Le code VB est regroupe dans des blocs appeles "procedures". Chaque procedure porte un nom qui la distingue. Ce nom est constitue de caracteres alphanumeriques et du signe souligne (les espaces sont interdits). Ce nom doit commencer par une lettre et ne doit pas depasser 255 caracteres.

Declaration
Comme une procedure peut en appeler une autre, leur declaration peut etre precedee des mots-cles suivants :
-Public : la procedure est accessible par toutes les procedures du projet. Pris par defaut, ce mot-cle peut etre omis.
-Private : la procedure est accessible uniquement par les procedures du meme module. Des procedures portant le meme nom peuvent se trouver dans des modules differents.

Ajouter une procedure
-Au besoin, cliquez Restaurer la fenetre pour reduire la fenetre Module2
-Cliquez dans la fenetre Module2 et tapez sub SaisieMessage ↵
VB ajoute l'instruction de fin de procedure End Sub et met en bleu les mots-cles qu'il a reconnus.
Vous pouvez acceder directement a une procedure en la selectionnant dans la liste Procedure du module.

Variables

Les variables permettent de stocker des valeurs intermediaires. Elles contiennent les types de donnees ci-apres :
-Byte : entier de 0 a 255
-Boolean : True ou False (vrai ou faux)
-Integer : entier de -32768 a 32767
-Long : entier de -2147483648 a 2147483647
-Single : valeur a virgule flottante en simple precision
-Double : valeur a virgule flottante en double precision
-Currency : monetaire de -922337203685477,5808 a 922337203685477,5807
-Date : du 1er janvier 100 au 31 decembre 9999
-Object : reference a des objets
-String : chaines de 0 a 2 milliards de caracteres
-Variant : tout type de valeurs numeriques ou chaines de caracteres.
Si l'on utilise une variable sans la declarer, elle prend le type Variant. Dans ce type particulier, c'est VB qui determine le type en fonction du contenu.
Les noms des variables suivent les memes regles que les noms des procedures.

Declaration des variables
Les variables se declarent avec la syntaxe suivante :
Dim nom_de_variable As type
Voici quelques syntaxes de declaration et d'affectation de valeurs :
Dim variable1 As Integer
Dim variable2 As String
variable1 = 12345
variable2 = "Chaine de caracteres alphanumeriques"
variable3 = #15/12/98#
Pour cette derniere ligne, la variable n'a pas ete declaree. Elle est de type Variant. Les signes "diese" indiquent une valeur de type date ou heure.
-Tapez dim Reponse as string ↵ dans la fenetre Module2 (Code)

Tableaux
Les tableaux sont des variables contenant plusieurs valeurs. On accede a chaque element d'un tableau en precisant son numero d'index. Les tableaux peuvent contenir plusieurs dimensions. Il faut preciser autant de numeros d'index qu'il y a de dimensions. Les tableaux doivent etre declares. Voici quelques syntaxes de declaration et d'affectation de valeurs pour des tableaux :
Dim tableau1(10) As Date
Dim tableau2(100,50) As String
tableau1(1) = #15/12/98#
tableau1(2) = #16/12/98#
tableau2(1;1) = "Clement"
tableau2(1;2) = "Jean-Francois"
Le tableau1 comporte une dimension de dix elements. Le tableau2 comporte deux dimensions, la premiere de 100 et la seconde de 50, soit 5000 elements au total. VB reserve de la place pour les tableaux. Declarez uniquement la taille necessaire pour ne pas encombrer la memoire.

Remarques

L'apostrophe permet d'ajouter des remarques dans le code. Les lignes de remarques sont ignorees a l'execution. Pour qu'une procedure soit comprehensible plusieurs mois apres sa conception, il est indispensable d'ajouter des commentaires.
-Tapez 'Saisie du nom de l'utilisateur ↵ dans la fenetre Module2
Les lignes de commentaires sont affichees en vert.


Fonction ou instruction ?

Les fonctions et les instructions VB executent des actions. Les fonctions retournent des valeurs alors que les instructions executent simplement des actions. On peut les comparer aux declarations Function et Sub.


InputBox et MsgBox

La fonction InputBox demande une valeur a l'utilisateur par une boite de dialogue. Comme il s'agit d'une fonction, il faut preciser le nom de la variable qui doit recevoir la donnee saisie. Demandons le nom de l'utilisateur.
-Tapez Reponse = inputbox("Tapez votre nom", "Votre nom") ↵
Le signe egal indique une affectation. On affecte au contenu de la variable Reponse le resultat de la fonction inputbox.
Les deux arguments de la fonction sont des textes affiches dans la boite et dans la barre de titre comme l'indique la syntaxe dans l'info-bulle des que vous tapez la parenthese.
Les arguments en gras sont obligatoires. Ceux entre crochets sont facultatifs. Les mots-cles As String indiquent que la fonction retourne une chaine de caracteres.
L'instruction MsgBox fait apparaitre un message dans une boite de dialogue. Affichons le nom de l'utilisateur et l'heure actuelle.
-Tapez msgbox Reponse & ", il est tres exactement " & time ↵
-& : additionne des chaines de caracteres
-Time (fonction) : retourne l'heure de l'ordinateur
-Au besoin, placez le curseur dans la procedure SaisieMessage
-Cliquez Executer Sub/Userform dans la barre d'outils
-Tapez votre nom dans la boite de dialogue
-Cliquez OK dans la boite Votre nom
-Cliquez OK dans la boite Microsoft Excel
La fonction InputBox a affecte a la variable Reponse la donnee que vous avez tapee. L'instruction MsgBox a affiche cette variable ainsi que l'heure.

Instructions de decision

If Then Else
L'instruction de decision If permet de faire des choix a l'interieur d'une procedure. Elle utilise la syntaxe suivante :
If condition Then instructions Else instructions
Elle peut aussi s'ecrire sur plusieurs lignes :
If condition Then
instructions
ElseIf condition Then
instructions
Else
instructions
End If
Les instructions Else et ElseIf sont facultatives. On peut ajouter autant d'instructions Elself que necessaire. La syntaxe sur plusieurs lignes est toujours plus claire, il est preferable de l'utiliser.
-Cliquez le menu Insertion Procedure
-Tapez IfThenElse ↵ dans Nom
En fonction d'une annee saisie, recherchons l'emplacement d'un dossier.
-Tapez le code ci-dessous
Pour plus de clarte, les lignes sont decalees avec la touche ⇆ a l'interieur de l'instruction If...End If. Ces touches de tabulation n'ont aucune incidence sur le deroulement du programme.
Public sub IfThenElse()
Annee = inputbox("Donnez l'annee du dossier")
If Annee >= 96 Then
Lieu = "le bureau"
ElseIf Annee >= 90 Then
Lieu = "la bibliotheque"
Else
Lieu = "la cave"
End if
Msgbox "Le dossier est dans " & Lieu
End sub
-Cliquez Executer Sub/UserForm dans la barre d'outils
-Tapez 98 dans la boite Microsoft Excel
-Cliquez OK pour valider la boite Microsoft Excel
Le programme affiche le resultat.
-Cliquez OK pour fermer le message
-Repetez les quatre etapes precedentes avec les annees 91 et 85

Select Case
L'instruction de decision Select permet de faire des choix a l'interieur d'une procedure. Elle simplifie l'instruction If quand on utilise plusieurs fois ElseIf. La syntaxe est la suivante :

Select Case expression numerique ou chaine
Case liste d'expressions
instructions
Case Else
instructions
End Select
On peut ajouter autant d'instructions Case que necessaire. Liste d'expressions sont des valeurs a comparer avec l'expression du Select Case. Plusieurs expressions sont separees par une virgule et les plages d'expression par le mot-cle To. L'instruction Case Else est facultative.
-Cliquez le menu Insertion Procedure
-Tapez SelectCase ↵ dans Nom
Affichons un message en fonction de l'heure actuelle.
-Tapez le code ci-dessous
Public sub SelectCase()
Select Case Hour (Time)
Case 0 To 6
Message = "Bonne nuit !"
Case 7
Message = "Bonjour !"
Case 8 to 11
Message = "Bonne matinee !"
Case 12, 13
Message = "Bon appetit !"
Case 14 To 19
Message = "Bon apres-midi !"
Case Else
Message = "Bonne soiree !"
End Select
msgbox Message
End sub
-Hour (Time): retourne une valeur entre 0 et 23 correspondant a l'heure actuelle
-Case 0 To 6 : on teste la plage de 0 a 6 heures
-Case 7 : on teste uniquement s'il est 7 heures
-Case 12, 13 : on teste s'il est 12 heures ou 13 heures
-Case Else : pour tous les autres cas
-Tapez F5 pour executer la procedure
-Cliquez OK pour fermer la boite Microsoft Excel


Instructions de boucle

Les instructions de boucle repetent plusieurs fois un meme groupe d'instructions.

For Next
L'instruction For...Next execute une ou plusieurs instructions un nombre de fois precis. Elle s'utilise avec la syntaxe suivante :
For compteur = debut To fin Step increment
instructions
Next compteur
La variable compteur va passer de la valeur de debut a la valeur de fin en augmentant a chaque boucle de la valeur de l'increment. Debut, fin et increment sont des variables ou des valeurs numeriques. Si Step n'est pas precise, increment prend par defaut la valeur 1.
On peut imbriquer plusieurs boucles comme l'illustre l'exemple des tables de multiplication.
-Cliquez le menu Insertion Procedure
-Tapez TablesMultiplication ↵ dans Nom
-Tapez le code ci-dessous
Public sub TablesMultiplication()
For i = 1 To 12
Debug.Print "*** Table de"; i; " ***"
For j = 1 to 10
Debug.Print i; " x "; j; "= "; i * j
Next j
Next i
End sub
-Print (methode) : appliquee a l'objet Debug, affiche des donnees dans une fenetre particuliere de VB (voir paragraphe Fenetre Execution).
-Au besoin, tapez Ctrl G pour afficher la fenetre Execution
La fenetre apparait soit en bas de l'ecran, soit comme une fenetre independante.
-Cliquez dans la procedure puis tapez F5 pour l'executer
Le resultat s'affiche dans la fenetre Execution.

Do Loop
L'instruction Do...Loop est un melange d'instructions de decision et d'instructions de boucle. La boucle est executee indefiniment jusqu'au moment ou la condition devient vraie (mot-cle Until) ou tant que la condition reste vraie (mot-cle While). Voici sa syntaxe :
Do Until|While condition
instructions
Loop
Si vous avez choisi Until et que la condition est deja vraie, la boucle n'est jamais executee.
De meme, si la condition est fausse au depart, la boucle n'est jamais executee avec While.
Pour que la boucle soit executee au moins une fois, il faut placer Until ou While apres l'instruction Loop.
-Cliquez dans la fenetre Module2 (Code) pour la selectionner
-Cliquez le menu Insertion Procedure
-Tapez MonsieurMadame ↵ dans Nom
La procedure qui suit demande une reponse a une question. Tant que la reponse est differente de "Louis", on demande une nouvelle reponse.
La troisieme ligne etant longue, elle n'est pas entierement visible a l'ecran.

Le caractere de continuite permet de separer une ligne logique en deux ou plusieurs lignes physiques.
-Pour ajouter un Caractere de continuite : appuyez sur la barre d'espace, sur la touche de soulignement (_) et sur la touche ↵
[Il n'est pas possible d'ajouter un caractere de continuite a l'interieur d'une chaine de carcateres. Par exemple, pour la troisieme ligne, le caractere de continuite ne peut pas etre insere entre les mots une et fille.]
-Tapez le code ci-apres :
Public sub MonsieurMadame()
Do
Reponse = inputbox("Monsieur et Madame Phine ont un fils" _
+Chr(10) + "Comment l'ont-ils appele?")
Loop While LCase(Reponse) <> "louis"
msgbox "Bravo ! C'est Louis Phine."
end sub
-Chr(10) : ajoute a la chaine le caractere ANSI 10 pour passer a la ligne suivante dans le message
-LCase : comme l'utilisateur peut melanger les majuscules et les minuscules, la fonction LCase convertit tous les caracteres de la reponse en minuscules.
-Tapez F5 pour executer la procedure
-Tapez votre reponse puis cliquez OK
-Cliquez OK pour fermer la boite Microsoft Excel


Portee des variables

Des qu'une procedure se termine avec l'instruction End Sub ou End Function, le contenu des variables est supprime. Ce sont des variables locales.
Pour que le contenu des variables soit conserve, il faut les declarer au niveau du module et non dans une procedure. De plus, leur contenu sera accessible par toutes les procedures. Ce sont des variables de type Public.
Ajoutons une variable de test en dehors d'une procedure.
-Selectionnez (Declarations) dans la liste Procedure [MonsieurMadame]
-Tapez Public y as integer ↵ au debut du module

Appel d'une autre procedure
Creons une procedure Principale qui appelle notre procedureTablesMultiplication.
-Tapez Ctrl Fin pour passer a la fin du module
-Tapez sub Principale ↵
Ajoutons deux variables de test.
-Tapez y = 10
-Tapez z = 20
Appelons la procedure TablesMultiplication.

-Tapez TablesMultiplication


Mode pas a pas

Quand on lance un projet, toutes les instructions sont executees les unes apres les autres. Si le code contient une erreur de logique, il est difficile de determiner a quelle ligne elle se produit.
La methode "pas a pas" permet de suspendre l'execution a chaque ligne pour vous laisser le temps d'examiner le resultat.

Executer un projet en pas a pas
-Cliquez avec le bouton droit sur la barre d'outils
-Cliquez Debogage pour cocher l'option
-Cliquez Pas a pas detaille dans la barre d'outils Debogage
La premiere instruction de la procedure Principale est selectionnee dans la fenetre Module2 (Code). Elle est surlignee en jaune et precedee de la fleche. Ce sera la prochaine instruction executee.
-Cliquez 4 fois Pas a pas detaille
Maintenant c'est la premiere instruction de la procedure TablesMultiplication qui est selectionnee.
-Cliquez 10 fois Pas a pas detaille


Fenetre Execution

La fenetre Execution permet d'afficher des resultats pour la mise au point des programmes, de consulter le contenu des variables ou d'effectuer des calculs.

Executer des instructions VB directement
-Cliquez dans la fenetre Execution en-dessous de 1 x 3 = 3
-Tapez print i,j ↵ pour connaitre le contenu de ces variables
-Tapez ? 2*3.14159*15 ↵ pour effectuer un calcul
Le point d'interrogation remplace la methode Print.
-Tapez msgbox "la variable j contient " & j ↵ pour executer cette instruction
-Cliquez OK pour fermer la boite Microsoft Excel

Contenu des variables
-Pointez le j de Next j dans la fenetre Module2 (Code)
L'info-bulle affiche le contenu actuel de la variable j.


Variables locales

-Cliquez Fenetre Variables locales dans la barre d'outils Debogage
Cette fenetre affiche le contenu des variables de la procedure en cours.
-Cliquez ... dans la fenetre Variables locales
-Double-cliquez VBAProject.Module2.Principale dans la liste Pile des appels
La fenetre Variables locales affiche les variables de la procedure Principale. Notez que la variable y n'apparait pas puisqu'elle fait partie du module.

-Cliquez + a gauche de Module2 dans la fenetre Variables locales
La variable y apparait maintenant. Declaree au niveau module, elle est donc accessible dans la procedure Principale.
La derniere ligne executee dans la procedure Principale est precedee d'une fleche dans la fenetre Module2 (Code).
-Cliquez ... dans la fenetre Variables locales
-Double-cliquez VBAProject.Module2.TablesMultiplication
-Cliquez + a gauche de Module2 dans la fenetre Variables locales
La variable y est aussi accessible par la procedure TablesMultiplication.
[La variable y est de type Integer puisque nous l'avons declaree comme telle. Les variables i et j sont de type Variant/Integer puisqu'elles ne sont pas declarees.]


Poursuivre l'execution

-Cliquez Continuer dans la barre d'outils
Le programme se deroule normalement et affiche le reste des tables.

Point d'arret

Pour ne pas s'arreter sur toutes les lignes avant d'arriver a celles qui vous interessent, il faut poser un point d'arret.
-Cliquez dans la marge en face de la ligne Debug.Print... de la procedure TablesMultiplication
-Selectionnez Principale dans la liste Procedure [TablesMultiplication]
-Cliquez Executer Sub/UserForm
Le projet s'execute normalement puis il est stoppe au point d'arret.
-Cliquez Pas a pas detaille dans la barre d'outils Debogage
L'execution se poursuit jusqu'a la ligne suivante.
-Cliquez Continuer
L'execution est de nouveau stoppee sur le point d'arret. Supprimons-le.
-Cliquez dans la marge en face de la ligne Debug.Print... de la procedure TablesMultiplication
-Cliquez Continuer
Le programme s'execute normalement.


Gestion des erreurs

Il existe trois types d'erreurs dans une procedure.
-Erreurs de syntaxe : elles sont detectees par VB quand vous appuyez sur ↵ a la fin d'une ligne de code ou quand vous cliquez a un autre endroit. Vous pouvez donc les corriger immediatement. La ligne qui contient une erreur est affichee en rouge.
-Erreurs de logique : elles sont plus difficiles a reperer. Pour les detecter, utilisez le mode pas a pas et les fenetres Execution et Variables locales.
-Erreurs exterieures : elels resultent d'elements exterieurs. Par exemple, si vous demandez a lire un fichier sur disquette alors que le lecteur n'en contient pas, ou bien si vous tapez un chiffre alors qu'une boite de dialogue attend une date.

-Selectionnez IfThenElse dans la liste Procedure
-Cliquez Executer Sub/UserForm
-Tapez L'an 2000 ↵ a la question Donnez l'annee du dossier
-Cliquez le bouton Debogage
La procedure IfThenElse s'affiche et la ligne qui a provoque l'erreur est surlignee.
On compare la variable Annee qui contient du texte avec une valeur numerique. Les deux valeurs sont incompatibles.
-Cliquez Reinitialiser dans la barre d'outils
-Modifiez la procedure comme suit :
Public Sub IfThenElse()
On Error GoTo ErreurIfThenElse
Debut:
Annee = inputbox("Donnez l'annee du dossier")
If Annee >= 96 Then
Lieu = "le bureau"
ElseIf Annee >= 90 Then
Lieu = "la bibliotheque"
Else
Lieu = "la cave"
End if
Msgbox "Le dossier est dans " & Lieu
Exit sub
ErreurIfThenElse:
If Err = 13 Then
Msgbox "Vous devez donner un nombre"
Resume Debut
Else
msgbox "Erreur No : " & Err & Chr(10) & "Erreur : " & Error(Err)
Stop
End if
End sub
-On Error GoTo : indique l'adresse de la procedure qui gere les erreurs
-Debut: et ErreurIfThenElse: sont des etiquettes qui indiquent le debut de la procedure principale et le debut de la procedure qui gere les erreurs
-Exit sub : evite que la procedure normale se poursuive par la procedure qui gere les erreurs (remplace End Sub)
-Err : retourne le numero de l'erreur
-Error() : retourne le message d'erreur en toutes lettres
-Stop : suspend la procedure
-Cliquez 4 fois Pas a pas detaille
-Tapez L'an 2000 ↵ a la question Donnez l'annee du dossier
-Cliquez Pas a pas detaille
La procedure a rencontre une erreur. Elle est deroutee vers la routine qui gere les erreurs. On teste Err pour determiner le type d'erreur (ici l'erreur numero 13, type incompatible).

-Cliquez 2 fois Pas a pas detaille
-Cliquez OK pour fermer la boite Microsoft Excel
-Cliquez Pas a pas detaille
Resume Debut supprime l'erreur et revient a la procedure principale.
-Cliquez Reinitialiser
L'erreur numero 13 est une erreur que nous avons prevue dans notre procedure. Mais il est possible que d'autres erreurs surviennent. C'est le role de Else dans l'instruction If. Toutes les autres erreurs passeront par l'instruction Stop qui suspend la procedure.
-Apres la ligne Debut: ajoutez la ligne essai = 1/0 ↵
-Cliquez Executer Sub/UserForm
L'instruction MsgBox affiche le numero et le type de l'erreur.
-Cliquez OK pour fermer la boite Microsoft Excel
La procedure est arretee a l'instruction Stop.
-Cliquez Reinitialiser
-Supprimez la ligne essai = 1/0
-Cliquez Enregistrer Macro2.xls pour sauver les modifications
-Cliquez x pour fermer la fenetre Execution
-Cliquez x pour fermer la fenetre Variables locales
-Cliquez avec le bouton droit sur une barre d'outils
-Cliquez Debogage pour oter la coche


Regrouper des actions

Il arrive bien souvent que l'on applique plusieurs methodes et que l'on modifie plusieurs proprietes pour un meme objet. Elle utilise la syntaxe suivante :
With objet
methodes et proprietes de l'objet (sans le nom de l'objet)
End with
-Double-cliquez Module1 dans l'arborescence de la fenetre Projet
-Selectionnez Macro3 dans la liste Procedure de la fenetre Module1 (Code)
-Modifiez la procedure Macro3 comme dans l'exemple ci-apres
Sub Macro3()
Sheets("Feuil1").Select
With Range("A1:B3")
.Select
.Formula = "Excel 97"
.RowHeight = 40
.PrintPreview
.AutoFormat Format:=xlRangeAutoFormatColor2, Width:=False
End With
End sub
Avec cette nouvelle syntaxe, les proprietes et les methodes comprises entre les instructions With et End with sont appliquees a l'objet Command1.

-Cliquez Enregistrer Macro2.xls pour sauver les modifications


Options d'edition

-Cliquez le menu Outils Options
-Cliquez l'onglet Format de l'editeur
-Police et Taille : police et taille utilisees pour taper le code
-Couleurs du code : selectionnez une entree dans la liste, puis selectionnez la couleur Premier plan, la couleur Arriere-Plan et la couleur Indicateur de la marge (un exemple est affiche dans la zone Apercu)
-Barre des indicaterus en marge : pour afficher ou non la barre des indicateurs (point d'arret, ligne a executer en pas a pas, etc.)
-Cliquez l'onglet Editeur
Toutes ces options definissent l'affichage et l'edition du code.
Si vous cochez l'option Declaration explicite des variables, vous serez oblige de declarer toutes les variables utilisees dans les procedures. Cette technique evite les erreurs de frappe et les confusions dans les noms. Nous vous conseillons de l'utiliser dans vos developpements. Les variables ne sont pas declarees dans les exemples de ce livre pour eviter de surcharger le texte.
-Cliquez OK pour fermer la boite Options
-Cliquez Affichage Microsoft Excel dans la barre d'outils
-Cliquez Fermer la fenetre pour fermer le classeur Macro2.xls.